DGL • Thema anzeigen - AVI abspielen, Problem

AVI abspielen, Problem

Moderator: DGL-Team

Seite 2 von 2

[ 19 Beiträge ]

Gehe zu Seite Vorherige 1, 2

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

berens

Betreff des Beitrags:

Verfasst: Mo Dez 11, 2006 17:12

DGL Member

Registriert: Mo Jul 17, 2006 13:16
Beiträge: 69

Ok, ich habs langsam auch hinbekommen:

Beim Nachprogrammieren bitte darauf achten, dass ShowText etc. auch Prozeduren aufruft, die GL-Befehle enthalten. Wenn das Video also nicht so aussieht wie hier in dem Demo-Programm, einfach mal die ShowText Befehle mitnehmen

Nächstes Ziel: Videotextur mit mehr als 256x256 Pixel. Man lernt immer dazu!

Vielen Dank an Lossy eX und tak2004 für die besondere Geduld. Thx!

Code:

 
// =============================================================================
//   OpenGL1.5 - VCL Template (opengl15_vcl_template.zip)
// =============================================================================
//   Copyright © 2003 by DGL - http://www.delphigl.com
// =============================================================================
//   Contents of this file are subject to the GNU Public License (GPL) which can
//   be obtained here : http://opensource.org/licenses/gpl-license.php
// =============================================================================
//   History :
//    Version 1.0 - Initial Release                            (Sascha Willems)
// =============================================================================
 
unit OpenGL15_MainForm;
 
interface
 
uses
  Windows,
  Messages,
  SysUtils,
  Classes,
  Graphics,
  Controls,
  Forms,
  Dialogs,
 
  vfw,
  dglOpenGL;
 
type
  TGLForm = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
    procedure FormKeyPress(Sender: TObject; var Key: Char);
    procedure GrabAVIFrame(frame: integer);
    procedure xUpdate(milliseconds: DWORD);
  private
    { Private-Deklarationen }
    Texture: TGLuint;
    Data: Pointer;
    LastFrame, Next: Integer;
    mpf: integer;
    bmih: BITMAPINFOHEADER;
    h_bitmap: HBITMAP;
    pdata: PGLubyte;
    fhdd: HDRAWDIB;
    frame: integer;
    lastTickCount: Cardinal;
    VideoWidth, VideoHeight: Integer;
    StartTick : Cardinal;
    Frames    : Integer;
    psi: TAVIStreamInfo;
    pavi: IAVIStream;
    pgf: IGetFrame;
  public
    RC        : HGLRC;
    DC        : HDC;
    VDC       : HDC; // VideoDeviceContext
    ShowFPS   : Boolean;
    FontBase  : GLUInt;
    FPS       : Single;
 
    procedure BuildFont(pFontName : String);
    procedure OpenAVI(szFile: LPCSTR);
    procedure PrintText(pX,pY : Integer; const pText : String);
    procedure ShowText;
  end;
 
var
  GLForm: TGLForm;
 
implementation
 
{$R *.dfm}
 
{$Region 'BuildFont'}
// =============================================================================
//  TForm1.BuildFont
// =============================================================================
//  Displaylisten für Bitmapfont erstellen
// =============================================================================
procedure TGLForm.BuildFont(pFontName : String);
var
 Font : HFONT;
begin
// Displaylisten für 256 Zeichen erstellen
FontBase := glGenLists(96);
// Fontobjekt erstellen
Font     := CreateFont(16, 0, 0, 0, FW_MEDIUM, 0, 0, 0, ANSI_CHARSET, OUT_TT_PRECIS, CLIP_DEFAULT_PRECIS,
                       ANTIALIASED_QUALITY, FF_DONTCARE or DEFAULT_PITCH, PChar(pFontName));
// Fontobjekt als aktuell setzen
SelectObject(DC, Font);
// Displaylisten erstellen
wglUseFontBitmaps(DC, 0, 256, FontBase);
// Fontobjekt wieder freigeben
DeleteObject(Font)
end;
{$EndRegion}
 
{$Region 'PrintText'}
// =============================================================================
//  TForm1.PrintText
// =============================================================================
//  Gibt einen Text an Position x/y aus
// =============================================================================
procedure TGLForm.PrintText(pX,pY : Integer; const pText : String);
begin
if (pText = '') then
 exit;
glPushAttrib(GL_LIST_BIT);
 glRasterPos2i(pX, pY);
 glListBase(FontBase);
 glCallLists(Length(pText), GL_UNSIGNED_BYTE, PChar(pText));
glPopAttrib;
end;
{$EndRegion}
 
{$Region 'ShowText'}
// =============================================================================
//  TForm1.ShowText
// =============================================================================
//  FPS, Hilfstext usw. ausgeben
// =============================================================================
procedure TGLForm.ShowText;
begin
// Tiefentest und Texturierung für Textanzeige deaktivieren
glDisable(GL_DEPTH_TEST);
glDisable(GL_TEXTURE_2D);
// In orthagonale (2D) Ansicht wechseln
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
glOrtho(0,640,480,0, -1,1);
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
PrintText(5,15, FloatToStr(FPS)+' fps');
glEnable(GL_DEPTH_TEST);
glEnable(GL_TEXTURE_2D);
end;
{$EndRegion}
 
{$Region 'FormCreate'}
// =============================================================================
//  TForm1.FormCreate
// =============================================================================
//  OpenGL-Initialisierungen kommen hier rein
// =============================================================================
procedure TGLForm.FormCreate(Sender: TObject);
begin
// Variablen initialisieren;
Data := NIL;
Texture := 0;
LastFrame := 0;
mpf := 0;
Frame := 0;
Next := 0;
VideoWidth := 0;
VideoHeight := 0;
 
// OpenGL-Funtionen initialisieren
InitOpenGL;
// Gerätekontext holen
DC := GetDC(Handle);
// Renderkontext erstellen (32 Bit Farbtiefe, 24 Bit Tiefenpuffer, Doublebuffering)
RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
// Erstellten Renderkontext aktivieren
ActivateRenderingContext(DC, RC);
// Tiefenpuffer aktivieren
glEnable(GL_DEPTH_TEST);
// Nur Fragmente mit niedrigerem Z-Wert (näher an Betrachter) "durchlassen"
glDepthFunc(GL_LESS);
// Löschfarbe für Farbpuffer setzen
glClearColor(0,0,0,0);
 
glGenTextures(1, @Texture);
glBindTexture(GL_TEXTURE_2D, Texture); // << Binden
glEnable(GL_TEXTURE_2D);
glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MAG_FILTER,GL_NEAREST);
glTexParameteri(GL_TEXTURE_2D,GL_TEXTURE_MIN_FILTER,GL_NEAREST);
glTexImage2D(GL_TEXTURE_2D, 0, GL_RGB, 256, 256, 0, GL_BGR, GL_UNSIGNED_BYTE, @data);
 
VDC := CreateCompatibleDC(0);
fhdd := DrawDibOpen;
 
OpenAVI('c:\1.avi');
// Displayfont erstellen
BuildFont('MS Sans Serif');
// Idleevent für Rendervorgang zuweisen
Application.OnIdle := ApplicationEventsIdle;
// Zeitpunkt des Programmstarts für FPS-Messung speichern
StartTick := GetTickCount;
 
end;
{$EndRegion}
 
{$Region 'FormDestroy'}
// =============================================================================
//  TForm1.FormDestroy
// =============================================================================
//  Hier sollte man wieder alles freigeben was man so im Speicher belegt hat
// =============================================================================
procedure TGLForm.FormDestroy(Sender: TObject);
begin
// Renderkontext deaktiveren
DeactivateRenderingContext;
// Renderkontext "befreien"
wglDeleteContext(RC);
// Erhaltenen Gerätekontext auch wieder freigeben
ReleaseDC(Handle, DC);
// Falls wir im Vollbild sind, Bildschirmmodus wieder zurücksetzen
ChangeDisplaySettings(devmode(nil^), 0);
end;
{$EndRegion}
 
procedure TGLForm.GrabAVIFrame(frame: integer);                                               // Grabuje požadovaný snímek z proudu
var
  lpbi: PBitmapInfoHeader;                                                            // Hlavièka bitmapy
begin
  lpbi := AVIStreamGetFrame(pgf,frame);                                               // Grabuje data z AVI proudu
  pdata := Pointer(Integer(lpbi) + abs(lpbi.biSize) + lpbi.biClrUsed * sizeof(RGBQUAD));   // Ukazatel na data
  DrawDibDraw(fhdd,VDC,0,0,256,256,lpbi,pdata,0,0,VideoWidth,VideoHeight,0);                    // Konvertování obrázku na požadovaný formát
  glTexSubImage2D(GL_TEXTURE_2D, 0, 0, 0, 256, 256, GL_BGR, GL_UNSIGNED_BYTE, data);  // Aktualizace textury
end;
 
{$Region 'ApplicationEventsIdle'}
// =============================================================================
//  TForm1.ApplicationEventsIdle
// =============================================================================
//  Hier wird gerendert. Der Idle-Event wird bei Done=False permanent aufgerufen
// =============================================================================
procedure TGLForm.ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
var
  tickCount: cardinal;
  Left_Min, Top_Min, Right_Max, Bottom_Max: Integer;
begin
  glMatrixMode(GL_PROJECTION_MATRIX);
  glLoadIdentity;
  glViewPort(0, 0, ClientWidth, ClientHeight);
  glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
 
  Left_Min := 0;
  Top_Min := 0;
  Right_Max := ClientWidth;
  Bottom_Max := ClientHeight;
 
  glOrtho(0,ClientWidth,ClientHeight,0, 0,128);
 
  GrabAVIFrame(frame);                                                // Nagrabuje požadovaný snímek videa
  glLoadIdentity;                                                     // Reset matice
  glBindTexture(GL_TEXTURE_2D, Texture);
 
  glBegin(GL_QUADS);
    glTexCoord2f(0,0); glVertex3f(0,Top_Min,0);
    glTexCoord2f(0,1); glVertex3f(0,Bottom_Max,0);
    glTexCoord2f(1,1); glVertex3f(Right_Max,Bottom_Max,0);
    glTexCoord2f(1,0); glVertex3f(Right_Max,0,0);
  glEnd;
 
  tickCount := GetTickCount;
  xUpdate(tickCount - lastTickCount);
  lasttickcount := tickCount;
 
ShowText;
 
// Hinteren Puffer nach vorne bringen
SwapBuffers(DC);
 
// Windows denken lassen, das wir noch nicht fertig wären
Done := False;
sleep(10);
 
// Nummer des gezeichneten Frames erhöhen
inc(Frames);
// FPS aktualisieren
if GetTickCount - StartTick >= 500 then
 begin
 FPS       := Frames/(GetTickCount-StartTick)*1000;
 Frames    := 0;
 StartTick := GetTickCount
 end;
end;
{$EndRegion}
 
{$Region 'ShowText'}
// =============================================================================
//  TForm1.FormKeyPress
// =============================================================================
procedure TGLForm.FormKeyPress(Sender: TObject; var Key: Char);
begin
case Key of
 #27 : Close;
end;
end;
{$EndRegion}
 
{$Region 'OpenAVI'}
procedure TGLForm.OpenAVI(szFile: LPCSTR);                                              // Otevøe AVI soubor
var
  bmi: BITMAPINFO;
begin
  AVIFileInit;                                                                  // Pøipraví knihovnu AVIFile na použití
  if AVIStreamOpenFromFile(pavi,szFile,streamtypeVIDEO,0,OF_READ,nil) <> 0 then // Otevøe AVI proud
    MessageBox(HWND_DESKTOP,'Failed To Open The AVI Stream','Error',MB_OK or MB_ICONEXCLAMATION); // Chybová zpráva
  AVIStreamInfo(pavi,psi,sizeof(psi));                                          // Naète informace o proudu
  VideoWidth := psi.rcFrame.Right - psi.rcFrame.Left;                                // Výpoèet šíøky
  VideoHeight := psi.rcFrame.Bottom - psi.rcFrame.Top;                               // Výpoèet výšky
  lastframe := AVIStreamLength(pavi);                                           // Poslední snímek proudu
  mpf := AVIStreamSampleToTime(pavi,lastframe) div lastframe;                   // Poèet milisekund na jeden snímek
  with bmih do
    begin
    biSize := sizeof(BITMAPINFOHEADER);                                         // Velikost struktury
    biPlanes := 1;                                                              // BiPlanes
    biBitCount := 24;                                                           // Poèet bitù na pixel
    biWidth := 256;                                                             // Šíøka bitmapy
    biHeight := 256;                                                            // Výška bitmapy
    biCompression := BI_RGB;                                                    // RGB mód
    end;
  bmi.bmiHeader := bmih;
  h_bitmap := CreateDIBSection(VDC,bmi,DIB_RGB_COLORS,data,0,0);
  SelectObject(VDC,h_bitmap);                                                  // Zvolí bitmapu do kontextu zaøízení
  pgf := AVIStreamGetFrameOpen(pavi,nil);                                       // Vytvoøí PGETFRAME použitím požadovaného módu
  if pgf = nil then                                                             // Neúspìch?
    MessageBox(HWND_DESKTOP,'Failed To Open The AVI Frame','Error',MB_OK or MB_ICONEXCLAMATION);
end;
{$EndRegion}
 
procedure TGLForm.xUpdate(milliseconds: DWORD);                                // Aktualizace pohybù ve scénì a stisk kláves
begin
  Inc(next,milliseconds);                                             // Zvìtšení next o uplynulý èas
  frame := next div mpf;                                              // Výpoèet aktuálního snímku
  if frame >= lastframe then                                          // Pøeteèení snímkù?
    begin
    frame := 0;                                                       // Pøetoèí video na zaèátek
    next := 0;                                                        // Nulování èasu
    end;
end;
 
end.
 

Nach oben

Passi

Betreff des Beitrags:

Verfasst: Mo Dez 11, 2006 17:47

DGL Member

Registriert: So Jul 17, 2005 12:59
Beiträge: 89

Das Abspielen von größeren Videos an sich ist eigentlich kein Problem (Texturgrößen entsprechend auf 512 oder 1024 ändern)..

nur habe ich ein Performanceproblem. Ich spiele ein 1024x1024 Video ab, mit dem Microsoft MPEG4 Codec komprimiert. Läuft auf meinem PC mit 110FPS (3800+, 7800GT). Auf meinem alten PC (1Ghz, GeForce2GTS) läuft das ganze nur noch mir gerade mal 6FPS. Obowhl das Video an sich ohne Probleme im Windows Media Player abgespielt wird.. kann ich da etwas dran ändern? Wenn ich die Auflösung auf 512x512 halbiere, läuft es mit ca. 18FPS..

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Mo Dez 11, 2006 18:34

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Eines darfst du nicht vergessen. Diese Methode zum Videosrendern ist alt. Das Bild wird erst noch mal irgend wohin gezeichnet und dort bereits schon in der Größe angepasst. Anschließend wird es dort wieder rauskopiert etc etc etc. Das ist verdammt viel zu tun und ältere Systeme haben irgendwo auch einfach ihre Grenze.

Eine Optimierung.
Die DIBSection des DCs auf 32 Bitfarbtiefe stellen und das Texturformat entsprechend auf BGRA ändern. Natürlich beim Erstellen der Textur als ersten Wert nicht mehr GL_RGB dann GL_RGBA und alle GL_BGR durch GL_BGRA ändern. Bzw die 24 bei der Struktur für CreateDIBSection auf 32 Stellen. Einige Grafikkarten haben "Probleme" mit 24 Bit Texturen. Da dauert das Uploaden länger als bei 32 Bit.

Ein ganz andere Weg ist zum Beispiel über den DirectShow Renderer. Dort bekommt man per Callback dann die Daten reingereicht und kann sie direkt hochladen.

Projekt: OpenGL VideoRender Filter
bzw. Schaut euch auch mal diese Thema an

Nach oben

Passi

Betreff des Beitrags:

Verfasst: Mo Dez 11, 2006 21:01

DGL Member

Registriert: So Jul 17, 2005 12:59
Beiträge: 89

Hi,

ok vielen Dank für Deine Infos

Habe mir nun mal den DirectShowRenderer von Hackbart angeschaut. Er läuft zwar, aber im Moment wird nur das weiße Quad ohne Textur gezeichnet. Was daran liegt, dass ich keine Videodatei geladen habe.. finde keine passende Funktion. Muss ich das noch selber implementieren?

Nach oben

Seite 2 von 2

[ 19 Beiträge ]

Gehe zu Seite Vorherige 1, 2

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.