DGL • Thema anzeigen - TexturProblem (glBitmap.pas)

TexturProblem (glBitmap.pas)

Moderator: DGL-Team

Seite 1 von 2

[ 16 Beiträge ]

Gehe zu Seite 1, 2 Nächste

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

bluenavajo

Betreff des Beitrags: TexturProblem (glBitmap.pas)

Verfasst: Do Mär 08, 2007 10:04

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Ich habe ein Problem beim Texturieren von Sonne Erde und Mond, die jeweils mit gluSphere gezeichnet werden. Bei der Sonne und der Erde werden die Texturen korrekt angezeigt, aber wenn die Texturen des Mondes und der Erde dazukommen bricht die Performance extrem (4fps) ein und die Textur des Mondes wird gar nicht dargestellt. Die Texturen werden bei Programmstart mit glBitmap geladen. Bei den Texturen handelt es sich um .tga Files der Größe 1000*500 pixel.
Kann es vielleicht daran liegen, dass die Texturen einfach zu groß sind und beim Vergeben der uv-Koordinaten auf den Spheres der Rechenaufwand einfach zu groß ist? Das mit Sonne, Erde, Mond stammt übrigens aus den Tutorial von Phobeus ;-)

Danke für den Anreiz

Code:

// =============================================================================
//   OpenGL1.5 - VCL Template (opengl15_vcl_template.zip)
// =============================================================================
//   Copyright © 2003 by DGL - http://www.delphigl.com
// =============================================================================
//   Contents of this file are subject to the GNU Public License (GPL) which can
//   be obtained here : http://opensource.org/licenses/gpl-license.php
// =============================================================================
//   History :
//    Version 1.0 - Initial Release                            (Sascha Willems)
// =============================================================================
 
unit OpenGL15_MainForm;
 
interface
 
uses
  Windows,
  Messages,
  SysUtils,
  Classes,
  Graphics,
  Controls,
  Forms,
  Dialogs,
  glBitmap,
  dglOpenGL;
 
type
  TGLForm = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
    procedure FormKeyPress(Sender: TObject; var Key: Char);
  private
    { Private-Deklarationen }
  public
    TexSonne,TexErdeD,TexMond,TexErdeN,TexUniverse  : TGluInt;
    BerechnungsZeit : Int64;
    Frequenz        : Int64;
    Position        : Double;
    Daytime   : boolean;
    Angle,Angle2     : Extended;
    Container : PGLUquadric;
    RC        : HGLRC;
    DC        : HDC;
    ShowFPS   : Boolean;
    FontBase  : GLUInt;
    StartTick : Cardinal;
    Frames    : Integer;
    FPS       : Single;
    procedure GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
    procedure BuildFont(pFontName : String);
    procedure PrintText(pX,pY : Integer; const pText : String);
    procedure ShowText;
  end;
 
var
  GLForm: TGLForm;
 
implementation
 
{$R *.dfm}
 
// =============================================================================
//  TForm1.GoToFullScreen
// =============================================================================
//  Wechselt in den mit den Parametern angegebenen Vollbildmodus
// =============================================================================
procedure TGLForm.GoToFullScreen(pWidth, pHeight, pBPP, pFrequency : Word);
var
 dmScreenSettings : DevMode;
begin
// Fenster vor Vollbild vorbereiten
WindowState := wsMaximized;
BorderStyle := bsNone;
ZeroMemory(@dmScreenSettings, SizeOf(dmScreenSettings));
with dmScreenSettings do
 begin
 dmSize              := SizeOf(dmScreenSettings);
 dmPelsWidth         := pWidth;                    // Breite
 dmPelsHeight        := pHeight;                   // Höhe
 dmBitsPerPel        := pBPP;                      // Farbtiefe
 dmDisplayFrequency  := pFrequency;                // Bildwiederholfrequenz
 dmFields            := DM_PELSWIDTH or DM_PELSHEIGHT or DM_BITSPERPEL or DM_DISPLAYFREQUENCY;
 end;
if (ChangeDisplaySettings(dmScreenSettings, CDS_FULLSCREEN) = DISP_CHANGE_FAILED) then
 begin
 MessageBox(0, 'Konnte Vollbildmodus nicht aktivieren!', 'Error', MB_OK or MB_ICONERROR);
 exit
 end;
end;
 
// =============================================================================
//  TForm1.BuildFont
// =============================================================================
//  Displaylisten für Bitmapfont erstellen
// =============================================================================
procedure TGLForm.BuildFont(pFontName : String);
var
 Font : HFONT;
begin
// Displaylisten für 256 Zeichen erstellen
FontBase := glGenLists(96);
// Fontobjekt erstellen
Font     := CreateFont(16, 0, 0, 0, FW_MEDIUM, 0, 0, 0, ANSI_CHARSET, OUT_TT_PRECIS, CLIP_DEFAULT_PRECIS,
                       ANTIALIASED_QUALITY, FF_DONTCARE or DEFAULT_PITCH, PChar(pFontName));
// Fontobjekt als aktuell setzen
SelectObject(DC, Font);
// Displaylisten erstellen
wglUseFontBitmaps(DC, 0, 256, FontBase);
// Fontobjekt wieder freigeben
DeleteObject(Font)
end;
 
// =============================================================================
//  TForm1.PrintText
// =============================================================================
//  Gibt einen Text an Position x/y aus
// =============================================================================
procedure TGLForm.PrintText(pX,pY : Integer; const pText : String);
begin
if (pText = '') then
 exit;
glPushAttrib(GL_LIST_BIT);
 glRasterPos2i(pX, pY);
 glListBase(FontBase);
 glCallLists(Length(pText), GL_UNSIGNED_BYTE, PChar(pText));
glPopAttrib;
end;
 
// =============================================================================
//  TForm1.ShowText
// =============================================================================
//  FPS, Hilfstext usw. ausgeben
// =============================================================================
procedure TGLForm.ShowText;
begin
// Tiefentest und Texturierung für Textanzeige deaktivieren
glDisable(GL_DEPTH_TEST);
glDisable(GL_TEXTURE_2D);
// In orthagonale (2D) Ansicht wechseln
glMatrixMode(GL_PROJECTION);
glLoadIdentity;
glOrtho(0,640,480,0, -1,1);
glMatrixMode(GL_MODELVIEW);
glLoadIdentity;
PrintText(5,15, FloatToStr(FPS)+' fps');
glEnable(GL_DEPTH_TEST);
glEnable(GL_TEXTURE_2D);
end;
 
// =============================================================================
//  TForm1.FormCreate
// =============================================================================
//  OpenGL-Initialisierungen kommen hier rein
// =============================================================================
procedure TGLForm.FormCreate(Sender: TObject);
begin
// Wenn gewollt, dann hier in den Vollbildmodus wechseln
// Muss vorm Erstellen des Kontextes geschehen, da durch den Wechsel der
// Gerätekontext ungültig wird!
 GoToFullscreen(1280, 1024, 32, 75);
                     
  if not QueryPerformanceFrequency(Frequenz) then // Frequenz ermitteln
   raise Exception.create('Kein Hardware Timer vorhanden');
  QueryPerformanceCounter(BerechnungsZeit); // Aktuelle Zeit ermitteln
 
// OpenGL-Funtionen initialisieren
InitOpenGL;
// Gerätekontext holen
DC := GetDC(Handle);
// Renderkontext erstellen (32 Bit Farbtiefe, 24 Bit Tiefenpuffer, Doublebuffering)
RC := CreateRenderingContext(DC, [opDoubleBuffered], 32, 24, 0, 0, 0, 0);
// Erstellten Renderkontext aktivieren
ActivateRenderingContext(DC, RC);
// Tiefenpuffer aktivieren
glEnable(GL_DEPTH_TEST);
// Nur Fragmente mit niedrigerem Z-Wert (näher an Betrachter) "durchlassen"
glDepthFunc(GL_LESS);
// Löschfarbe für Farbpuffer setzen
glClearColor(0,0,0.2,0);
// Displayfont erstellen
BuildFont('MS Sans Serif');
// Idleevent für Rendervorgang zuweisen
Application.OnIdle := ApplicationEventsIdle;
// Zeitpunkt des Programmstarts für FPS-Messung speichern
StartTick := GetTickCount;
LoadTexture('myTex\sunmap.tga',TexSonne,false);
LoadTexture('myTex\earthmap.tga',TexErdeD,false);
LoadTexture('myTex\earthnightmap.tga',TexErdeN,false);
LoadTexture('myTex\mond.tga',TexMond,false);
LoadTexture('myTex\universe.tga',TexUniverse,false);
glGetError;
end;
 
// =============================================================================
//  TForm1.FormDestroy
// =============================================================================
//  Hier sollte man wieder alles freigeben was man so im Speicher belegt hat
// =============================================================================
procedure TGLForm.FormDestroy(Sender: TObject);
begin
{glDeleteTextures(1,texSonne);
glDeleteTextures(1,texErde);
glDeleteTextures(1,texMond);}
gluDeleteQuadric(Container);
// Renderkontext deaktiveren
DeactivateRenderingContext;
// Renderkontext "befreien"
wglDeleteContext(RC);
// Erhaltenen Gerätekontext auch wieder freigeben
ReleaseDC(Handle, DC);
// Falls wir im Vollbild sind, Bildschirmmodus wieder zurücksetzen
ChangeDisplaySettings(devmode(nil^), 0);
end;
 
//==============================================================================
// Der Render-Abschnitt
//==============================================================================
// Hier werden die Objekte gerendert.
//==============================================================================
 
 
 
// =============================================================================
//  TForm1.ApplicationEventsIdle
// =============================================================================
//  Hier wird gerendert. Der Idle-Event wird bei Done=False permanent aufgerufen
// =============================================================================
procedure TGLForm.ApplicationEventsIdle(Sender: TObject; var Done: Boolean);
var i:integer;
    AktuelleZeit: Int64;
begin
// Farb- und Tiefenpuffer löschen
glClear(GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
// In die Projektionsmatrix wechseln
glMatrixMode(GL_PROJECTION);
// Identitätsmatrix laden
glLoadIdentity;
// Viewport an Clientareal des Fensters anpassen
glViewPort(0, 0, ClientWidth, ClientHeight);
// Perspective, FOV und Tiefenreichweite setzen
gluPerspective(60, ClientWidth/ClientHeight, 1, 128);
 
// In die Modelansichtsmatrix wechseln
glMatrixMode(GL_MODELVIEW);
// Identitätsmatrix laden
glLoadIdentity;
Container := gluNewQuadric();
glRotatef(Angle,1,0,0);
glPushMatrix();
glRotatef(90,1,0,0);
glDepthMask(false);
glBindTexture(GL_TEXTURE_2D,TexUniverse);
glEnable(GL_TEXTURE_2D);
gluQuadricTexture(Container,true);
gluSphere(Container,3,10,10);
glDisable(GL_TEXTURE_2D);
glDepthMask(true);
glPopMatrix();
glTranslatef(0,0,-10);
glTranslatef(0,0,Angle2);
//glRotatef(Angle,1,0,0);
  glBindTexture(GL_TEXTURE_2D,TexSonne);
  glEnable(GL_TEXTURE_2D);
  //glColor3f(255,140,0);
  //gluQuadricTexture(Container,true);
  gluSphere(Container,1,40,40);
  glDisable(GL_TEXTURE_2D);
 
  glRotatef(Position,0,1,0);
  glPushMatrix();
    glTranslatef(-4,0,0);
    glRotatef(90,1,0,0);
    if DayTime = false then
      glBindTexture(GL_TEXTURE_2D,TexErdeD);
    if Daytime = true then
      glBindTexture(GL_TEXTURE_2D,TexErdeN);
    glEnable(GL_TEXTURE_2D);
    gluQuadricTexture(Container,true);
    //glColor3f(0,0,255);
    gluSphere(Container,0.5,20,20);
    glDisable(GL_TEXTURE_2D);
      glPushMatrix();
        glRotatef(Position*5,0,0,1);
        glTranslatef(-1,0,0);
        glBindTexture(GL_TEXTURE_2D,TexMond);
        glEnable(GL_TEXTURE_2D);
        gluSphere(Container,0.1,10,10);
        glDisable(GL_TEXTURE_2D);
      glPopMatrix();
    glRotatef(90,1,0,0);
  glPopMatrix();
ShowText;
 
// Hinteren Puffer nach vorne bringen
SwapBuffers(DC);
 
// Windows denken lassen, das wir noch nicht fertig wären
Done := False;
 
// Nummer des gezeichneten Frames erhöhen
inc(Frames);
// FPS aktualisieren
if GetTickCount - StartTick >= 500 then
 begin
 FPS       := Frames/(GetTickCount-StartTick)*1000;
 Frames    := 0;
 StartTick := GetTickCount
 end;
 QueryPerformanceCounter(AktuelleZeit);
 Position := 10*((AktuelleZeit-Berechnungszeit)/Frequenz)+Position;
 Berechnungszeit := AktuelleZeit;
 if Position = 360 then
   Position := 0;
 
 glGetError;
end;
 
// =============================================================================
//  TForm1.FormKeyPress
// =============================================================================
procedure TGLForm.FormKeyPress(Sender: TObject; var Key: Char);
begin
case Key of
 #27 : Close;
 #119: Angle := Angle+2;
 #115: Angle := Angle-2;
 #110: DayTime := true;
 #100: Daytime := false;
 #113: Angle2 := Angle2+0.5;
 #101: Angle2 := Angle2-0.5;
 
end;
end;
 
end.

Hier is der Downloadlink für das komplette Projekt, weil ihr ja die Texturen nicht habt: http://rapidshare.com/files/19979684/Sonnensystem.rar.htmll

Zuletzt geändert von bluenavajo am Do Mär 08, 2007 16:19, insgesamt 5-mal geändert.

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 10:16

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Ich habe ein Déjà Vu.

Die Texturen müssen als Höhe/Breite eine Potenz von 2 haben. Passe deine Textur mal auf 1024x512 an. Demit sollte es dann gehen. Und die Größe ist schon recht anständig aber ich denke das ist alles noch halb so wild.

Nach oben

bluenavajo

Betreff des Beitrags: re

Verfasst: Do Mär 08, 2007 10:25

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Jo nur gehts. Danke! Aber die Textur für den Mond seh ich immernoch nich. Kann es sein, dass die Textur für den kleinen Popelmond einfach zu groß is und ich deswegen nichts seh?

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 11:49

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Hmmm. Also eigentlich sieht das soweit okay aus. Du machst ja bei dem Mond nichts anders als wie bei der Erde. Und gluSphere benutzt automatisch die gesammte Größe der Textur. Von daher sollte das so gehen.

Prüfe mal an verschiedenen Stellen (Nach dem Initialisieren, Nach dem Rendern) ob du Fehler bekommen hat. Das geht mit dem Aufruf von glGetError. Wenn ja dann schaue mal ob du das evtl noch etwas näher eingrenzen kannst.

Du solltest im übrigen deine mit gluNewQuadric erstellten quadrics auch wieder frei geben. Sonst hast du ein Speicherloch. Und eigentlich sollte ein quadric auch reichen.

PS: Stehen deine Texturen eigentlich auf dem Kopf? "Normal" sollten sie es.

Nach oben

bluenavajo

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 14:14

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Nein die stehen glaub ich nicht auf dem Kopf. Das war doch bei dem Loader dass er die Texturen umgekehrt in den Speicher schreibt oder? Also ich hab das nichts verändert. Ich musste nur die Erde einnal um 90° drehen weil die Textur so auf der Seite zu liegen schien. Bei der Gelegenheit: Kannst du mir auch noch erklären wie das mit den glDeleteTextures funktioniert. Das hatte ich unten auskommentiert, weil es irgendwie nich ging. PS: Ich hab oeben nochmal den neuen code gepostet. Nach dem Initialisieren und nach dem Rendern liefert glGetError keine Meldung.

Nach oben

bluenavajo

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 14:50

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Ich hab da noch eine Sache entdeckt. Wenn ich versuchshalber mal die Texturen vom Mond weglasse und ihm einfach nur eine Farbe gebe (ich hab Magenta genommen) dann wird nicht nur der Mond bunt, sondern auch Sonne und Erde inklusive der Textur darauf.

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 14:59

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Auf der Seite liegen. Hmmm. Finde ich irgendwie seltsam. Na ja. Lässt sich ja alles drehen. Und ja ich lade die Texturen anders als alle anderen. Weil ich es nicht einsehe, dass sie auf dem Kopf stehen müssen vor allem, wenn einige Funktionen von OpenGL Texturen so verlangen wie ich sie habe.

quadrics gibst du mit dem Befehl gluDeleteQuadric wieder frei.

Bei glDeleteTextures übergibst du eine Anzahl und einen Pointer auf die die TextureID und schon ist sie gelöscht. Du kannst sowohl bei GenTexture als auch bei DeleteTextures mehrere Namen erstellen oder freigeben lassen. Das sind normal Arrays oder besser gesagt ein Pointer auf das erste Element. Aber wenn man nur eine hat, dann kann man auch direkt einen Pointer auf eine Variable übergeben.

Code:

glDeleteTextures(1, @TexMond);

PS: Ich persönlich empfehle eigentlich eher die Benutzung der Klasse TglBitmap2D die in der glBitmap.pas enthalten ist. Weil die Möglichkeiten die man mit der Funktion hat entsprechen in etwa 5% dessen was man mit der Klasse an Möglichkeiten hat. Wenn es ausreicht. Okay. Aber so würde sich die Klasse komplett um die Verwaltung kümmern und hätte mehr Einstellungsmöglichkeiten.

Zu dem Mond. Ich habe keine Ahnung woran das liegen könnte. Ich bin derzeit auf Arbeit. Da kann ich nicht aber wenn ich heute abend zu hause bin, dann schaue ich mir das mal in ruhe an. Ich denke dann sollte sich das auch klären lassen.

Bunt: Du musst vor dem Zeichnen der Sonne natürlich dort die normale Farbe wieder setzen. OpenGL merkt sich das über die Framegrenzen hinweg. Aber was du mit Bunt beim Mond meinst verstehe ich nicht.

Nach oben

bluenavajo

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 15:02

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Ok Problem gelöst. Es lag an der Mondtextur. Die .tga Datei schien wohl irgendwie beschädigt. Ich habs mal mit ner anderen MondTextur im Jpeg Format versucht und dann ging es.

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 15:06

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Konntest du die Textur in Grafikprogrammen laden? Falls ja könntest du mir die evtl mal per Mail zuschicken? Meine Adresse findest du auf der Teamseite. Da ich TGAs vollständig per Hand lade versuche ich die natürlich bestmöglich zu unterstützen.

Nach oben

bluenavajo

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 16:02

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Klar schick ich dir. Ich hab die Textur erst im Jpeg Format gehabt und dann mit Adobe Photoshop CS in nen Tga File umgewandelt.

Nach oben

bluenavajo

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 16:18

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Hier mal nen kleines Foto vom Ergebnis. PS.: Ich hab den Quelltext oben nochmal geändert.
Würd mich freuen wenn ihr vielleicht mal nen kleines Statement dazu abgeben könntet.
Habt ihr ne Idee wie man z.B ne Atmosphäre um die Erde Rendern kann?

http://img403.imageshack.us/img403/2349/sonnensystemcm1.jpg

// edit Lossy: Das Bild ist von den Ausmaßen ein bisschen Groß deswegen als Link

Nach oben

MatReno

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 17:05

DGL Member

Registriert: Mo Jan 31, 2005 11:02
Beiträge: 432
Wohnort: Rheinlandpfalz

Sieht schon ganz hübsch aus, nur die Universum-textur sieht etwas verwaschen aus.
Für die Atmosphäre könntest du noch eine etwas größere Kugel um die Erde zeichnen mit
Wolkentextur und Additivem oder Alpha Blending. Die Textur sollte sich dann natürlich auch bewegen, das kannst
du dann ganz bequem per TextureMatrix machen. (einfach in den TextureMatrix Modus wechseln und dann die Textur translaten)
Gruß,
Matreno

_________________
http://texelviews.delphigl.com

Nach oben

bluenavajo

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 17:54

DGL Member

Registriert: So Mai 07, 2006 20:20
Beiträge: 20

Ich hab leider keine bessere Textur für die Sky Sphere bekommen. Weiss jemand von euch wo man etwas höher aufgelöstes bekommt oder wie man das allgemein besser hinbekommt?

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 18:01

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2067
Programmiersprache: C++

Die Nasa kann helfen:
http://visibleearth.nasa.gov/view_set.php?categoryID=2364
Sogar mit 21600 x 10800 falls interesse besteht

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

Lossy eX

Betreff des Beitrags:

Verfasst: Do Mär 08, 2007 18:17

DGL Member

Registriert: Do Dez 05, 2002 10:35
Beiträge: 4234
Wohnort: Dortmund

Habe mir die Textur einmal angesehen und ich weiß was das "Problem" dabei ist. Diese Textur ist ein Graustufenbild. Das bedeutet, dass das Bild nur einen einzigen Kanal mitbringt. Wärend aber bei dem JPEG 3 Kanäle vorhanden sind. Die aber alle 3 das Gleiche beinhalten. (Wobei JPEG auch Graustufen kann.) In jedem Falle ist eine Textur mit nur einem Kanal auch wesentlich Speicherschonender. Bei der Größe der Texturen nicht unbedingt von Nachteil.

Die glBitmap nimmt bei einen Kanal diesen immer als Alpha. Das hat dafür gesorgt, dass du keine Farbe hattest obwohl das Bild richtig geladen wurde. Mit der Methode LoadTextures kannst du darauf keinen Einfluss nehmen. Objekt orientiert sähe der entsprechende Code wie folgt aus.

Code:

  Tex := TglBitmap2D.Create;
  Tex.LoadFromFile('moonmap.tga');
  Tex.InternalFormat := ifLuminance;  // Das ist wichtig. Dort wird ein anderes Format gesetzt.
  Tex.GenTexture;

Wenn du gerne mit IDs arbeitest benötigst du noch dieses Stück.

Code:

  MoonID := Tex.ID;
  Tex.DeleteTextureOnFree := False;  // Verhindert, dass die Texture gelöscht wird
  Tex.Free;

Die ist dann genau wie die Methode LoadTextures. Nur, dass für die eine spezielle Textur das Format geändert wird.

Nach oben

Seite 1 von 2

[ 16 Beiträge ]

Gehe zu Seite 1, 2 Nächste

Foren-Übersicht » Programmierung » Einsteiger-Fragen

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 15 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.