DGL • Thema anzeigen - Bezier Curve - how to reference all points in the curve?

Bezier Curve - how to reference all points in the curve?

Moderator: DGL-Team

Seite 1 von 1

[ 3 Beiträge ]

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

dpm_dpmartin

Betreff des Beitrags: Bezier Curve - how to reference all points in the curve?

Verfasst: So Aug 19, 2007 13:44

DGL Member

Registriert: Mi Jan 24, 2007 00:44
Beiträge: 144

Hello,

I had the idea that certain UI components of my project could 'fly away' when I decided to move to another screen. Sure, I could just send them along a straight +X or +Y line until they disappeared from the screen, but I thought that it would be very nice looking to have them follow a flight plan that was described by a curve - maybe even a random curve - but a curve anyway.

So, I've started educating myself about OpenGL and calculating and drawing Bezier curves. Here is the entirety of my code - it is pretty straightforward and will run easily (just a TForm, with a client-aligned TPanel and a TTimer). This code calculates a curve via four control points and is able to display it on the screen - as well as displaying each point on the curve and the control points connected via a thin red line.

What I'm curious about is the code at lines 137 and 148 - the lines that use glEvalCoord1f to apparently draw out a GL_POINT (or a part of a LINE_LOOP) by referencing some values it seems to have pre-calculated with the call to glMap1f earlier - or is calculating on the fly.

While calculating my curve, I would prefer to be able pre-calculate and store the X, Y and Z of each point on the curve in an array - so I can look them up later - glEvalCoord1f is obviously pulling out the correct details - but 1) I don't really know where it is getting them from and 2) I don't know if I can access them in code so I can use glVertex3f to display things.

Is there a way of 1) setting up my control points, 2) setting a number of segments (level of detail), 3) calculating the curve according to the control points and number of segments (level of detail) I want and 4) storing the values of each point on the curve in X, Y and Z format in an array, so that I can then 5) reference them so my moving objects can follow some kind of flight plan?

glEvalCoord1f is great in that it obviously returns or uses some form of X, Y and Z values for the LINE_LOOP and GL_POINTs loop it is being used in - but it is not a function, so I don't know how to get my X, Y and Z values from it... does that make sense?

Code:

unit Main;
 
interface
 
uses
  OpenGL, Windows, SysUtils, Classes, Controls, Forms, StdCtrls, ComCtrls, ExtCtrls;
 
const
  LevelOfDetail = 20;
  NumberOfControlPoints = 4;
 
type
  TPoint = record
    X, Y, Z : GLFloat;
  end;
 
  TfrmMain = class(TForm)
    Timer1 : TTimer;
    pOGL : TPanel;
    procedure FormCreate (Sender : TObject);
    procedure Timer1Timer (Sender : TObject);
  private
    procedure Draw;
  public
  end;
 
var
  frmMain : TfrmMain;
  ControlPoints : array[0..NumberOfControlPoints - 1] of TPoint;
  Colours : array[0..LevelOfDetail] of array[0..2] of GLFloat;
  Rotation : GLFloat = 0;
 
 
implementation
 
 
{$R *.DFM}
 
 
procedure SetupPixelFormat ( DC : HDC
                           );
const
   PFD : TPIXELFORMATDESCRIPTOR = (
         nSize : SizeOf (TPIXELFORMATDESCRIPTOR); nVersion : 1;
         dwFlags : PFD_SUPPORT_OPENGL or PFD_DRAW_TO_WINDOW or PFD_DOUBLEBUFFER;
         iPixelType : PFD_TYPE_RGBA;
         cColorBits : 24; cRedBits : 0; cRedShift : 0; cGreenBits : 0; cGreenShift : 0;
         cBlueBits : 0; cBlueShift : 0; cAlphaBits : 0; cAlphaShift : 0; cAccumBits : 0;
         cAccumRedBits : 0; cAccumGreenBits : 0; cAccumBlueBits : 0; cAccumAlphaBits : 0;
         cDepthBits : 16; cStencilBits : 0; cAuxBuffers : 0; iLayerType : PFD_MAIN_PLANE;
         bReserved : 0; dwLayerMask : 0; dwVisibleMask : 0; dwDamageMask : 0);
var
  PixelFormat : Integer;
begin
   PixelFormat := ChoosePixelFormat (DC,@PFD);
   if (PixelFormat = 0) then
   begin
     Exit;
   end;
 
   if (SetPixelFormat (DC,PixelFormat,@PFD) <> True) then
   begin
     Exit;
   end;
end;
 
 
procedure TfrmMain.FormCreate ( Sender : TObject
                              );
var
  DC : HDC;
  RC : HGLRC;
  Loop : Integer;
begin
  DC := GetDC (pOGL.Handle);
  SetupPixelFormat (DC);
  RC := wglCreateContext (DC);
  wglMakeCurrent (DC,RC);
 
  { Set up the control points for the Bezier curve... }
  ControlPoints[0].X := -4;
  ControlPoints[0].Y := -4;
  ControlPoints[0].Z := -2;
 
  ControlPoints[1].X := -2;
  ControlPoints[1].Y := 6;
  ControlPoints[1].Z := 0;
 
  ControlPoints[2].X := 0;
  ControlPoints[2].Y := -2;
  ControlPoints[2].Z := 0;
 
  ControlPoints[3].X := 4;
  ControlPoints[3].Y := 4;
  ControlPoints[3].Z := -3;
 
  Randomize;
  { Calculate colours for each segment of the created curve. }
  for Loop := 0 to LevelOfDetail do
  begin
    Colours[Loop][0] := Random (100) / 100;
    Colours[Loop][1] := Random (100) / 100;
    Colours[Loop][2] := Random (100) / 100;
  end;
  glClearColor (0,0,0,1);
 
  glMap1f (GL_MAP1_VERTEX_3,0,1,3,4,@ControlPoints[0]);
  glEnable (GL_MAP1_VERTEX_3);
  glShadeModel (GL_FLAT);
 
  glMatrixMode (GL_PROJECTION);
  glLoadIdentity;
  gluPerspective (45,frmMain.Width / frmMain.Height,1,100);
  glMatrixMode (GL_MODELVIEW);
end;
 
 
procedure TfrmMain.Draw;
var
  Loop : Integer;
begin
  glClear (GL_COLOR_BUFFER_BIT or GL_DEPTH_BUFFER_BIT);
  glLoadIdentity;
  glTranslatef (0,0,-15);
 
  glRotatef (Sin (GetTickCount / 500) * 60,1,0,0);
  glRotatef (Sin (GetTickCount / 600) * 30,0,1,0);
  glRotatef (Sin (GetTickCount / 2000) * 140,0,0,1);
 
  { Draw the actual segements of the Bezier curve. }
  glLineWidth (4);
  glBegin (GL_LINE_STRIP);
    for Loop := 0 to LevelOfDetail do
    begin
      glColor3f (Colours[Loop][0],Colours[Loop][1],Colours[Loop][2]);
      { How do I really know what X, Y and Z this is? }
      glEvalCoord1f (Loop / LevelOfDetail);
    end;
  glEnd;
 
  { Draw each point along the Bezier curve... }
  glColor3f (1,1,0);
  glPointSize (5);
  glBegin (GL_POINTS);
    for Loop := 0 to LevelOfDetail do
    begin
      { Again - how can my X, Y and Z be obtained? }
      glEvalCoord1f (Loop / LevelOfDetail);
    end;
  glEnd;
 
  { Draw the control points of the Bezier curve... }
  glColor3f (1,0,0);
  glLineWidth (1);
  glBegin (GL_LINE_STRIP);
    for Loop := 0 to 3 do
    begin
      { Obviously I know what my X, Y and Z are for these... }
      glVertex3f (ControlPoints[Loop].X,ControlPoints[Loop].Y,ControlPoints[Loop].Z);
    end;
  glEnd;
 
  SwapBuffers (wglGetCurrentDC);
end;
 
 
procedure TfrmMain.Timer1Timer ( Sender : TObject
                               );
begin
  Draw;
end;
 
 
end.

_________________
Cheers, DpM
http://www.hmusiccentre.org.uk

Nach oben

i0n0s

Betreff des Beitrags:

Verfasst: So Aug 19, 2007 14:26

Ernährungsberater

Registriert: Sa Jan 01, 2005 17:11
Beiträge: 2067
Programmiersprache: C++

Casteljau:
b_k^n (x) := x_k, k = 0,..., n;
b_k^(j+1) (x) := u_o(x|I) b_k^j (x) + u_1(x|I) b_(k+1)^j (x), k = 0,..., n - j - 1;

where u_0 and u_1 are "baryzentrische Koordinaten" which meens:
u_0(x|I) := (t_1 - x) / (t_1 - t_0)
and
u_1(x|I) := (x - t_0) / (t_1 - t_0)
where t_0 and t_1 are the points at the border of the interval I.

b_0^n(x) is the value of the bezier curve at point x.

_________________
Steppity,✲steppity,✴step,❆step,✳step! :twisted:

❆ ❄ ❄ ❄ ❅ ❄ ❆ ❄ ❅ ❄ ❅ ❄ ❅ ❄ ❄
❅ ☃ ❄ ❄ ❄ ❅ ❄ ❄ ❄ ❅ ❄ ☃ ❄ ❆ ❄ ❄

Nach oben

dpm_dpmartin

Betreff des Beitrags: Success!

Verfasst: So Aug 19, 2007 14:27

DGL Member

Registriert: Mi Jan 24, 2007 00:44
Beiträge: 144

S'OK... got it. Not exactly got it figured out - but got it working anyway with:

Code:

function TfrmMain.GetPointOnCurve ( ControlPoint1, ControlPoint2, ControlPoint3, ControlPoint4 : TPoint;
                                    CurvePoint : GLFloat
                                  ) : TPoint;
var
  V1, V2, V3 : GLFloat;
  Returning : TPoint;
begin
  V1 := 1 - CurvePoint;
  V2 := V1 * V1 * V1;
  V3 := CurvePoint * CurvePoint * CurvePoint;
 
  Returning.X := V2 * ControlPoint1.X + 3 * CurvePoint * V1 * V1 * ControlPoint2.X + 3 * CurvePoint * CurvePoint * V1 * ControlPoint3.X + V3 * ControlPoint4.X;
  Returning.Y := V2 * ControlPoint1.Y + 3 * CurvePoint * V1 * V1 * ControlPoint2.Y + 3 * CurvePoint * CurvePoint * V1 * ControlPoint3.Y + V3 * ControlPoint4.Y;
  Returning.Z := V2 * ControlPoint1.Z + 3 * CurvePoint * V1 * V1 * ControlPoint2.Z + 3 * CurvePoint * CurvePoint * V1 * ControlPoint3.Z + V3 * ControlPoint4.Z;
 
  GetPointOnCurve := Returning;
end;
 

...and:

Code:

  glColor3f (1,1,0);
  glPointSize (5);
  glBegin (GL_POINTS);
    T := 0;
    for Loop := 0 to LevelOfDetail do
    begin
      ThisPoint := GetPointOnCurve (ControlPoints[0],ControlPoints[1],ControlPoints[2],ControlPoints[3],T);
      glVertex3f (ThisPoint.X,ThisPoint.Y,ThisPoint.Z);
      T := T + 1 / LevelOfDetail;
    end;
  glEnd;
 
 

Do I fully understand it? No. Do I understand that it does what I want? Yes. Am I happy with it? Yes.

_________________
Cheers, DpM
http://www.hmusiccentre.org.uk

Nach oben

Seite 1 von 1

[ 3 Beiträge ]

Foren-Übersicht » English » English Programming Forum

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 13 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.