DGL • Thema anzeigen

Xenorate 3

Moderator: DGL-Team

Seite 1 von 3

[ 36 Beiträge ]

Gehe zu Seite 1, 2, 3 Nächste

Druckansicht

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

Finalspace

Betreff des Beitrags: Xenorate 3

Verfasst: Mo Jul 05, 2004 13:48

DGL Member

Registriert: Mi Okt 16, 2002 15:06
Beiträge: 1012

Meinungen, Verbesserungsvorschläge, Kritik hier posten !

Danke,
Finalspace

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Mo Jul 05, 2004 15:06

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Wollte nur mal kurz anmerken das ich beim schliessen dieser Testversion die du gepostet hast ne schöne Windowsmeldung "Xenorate.exe - Fehler in Anwendung..." bekomme, und zwar mehrmals.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Finalspace

Betreff des Beitrags:

Verfasst: Mo Jul 05, 2004 15:16

DGL Member

Registriert: Mi Okt 16, 2002 15:06
Beiträge: 1012

Da gehts dann schon los mit Rechner abhängigkeiten

Also hier im geschäft tuts einwandfrei beim beenden.

Da du aber gesagt hast das der fehler mehrmals kommt, kann gut sein das der Update Thread noch läuft.
Und somit der fehler ab und zu mal kommt beim beenden, werde das überprüfen...

Du hast keine idee wie ich so art Debug Protokoll machen kann welches mir wirklich ursache von Fehlern anzeigt ?
Damit hatte ich schon in xeno 2 probs

Danke für die info !

Nach oben

Sascha Willems

Betreff des Beitrags:

Verfasst: Mo Jul 05, 2004 15:19

DGL Member

Registriert: Mo Sep 23, 2002 19:27
Beiträge: 5812
Programmiersprache: C++

Habs jetzt mehrmals getestet, und der Fehler kam eigentlich immer. Ist jedesmal ein Lesefehler in einem bestimmten Speicherbereich. (Evtl. hilft das ja)

Zum Thema Fehlerlog : Da würde ich konsequent mit try...except...finally-Blöcken arbeiten, die dann zur Laufzeit genutzt werden sollten um bei Fehlern genaue Infos auszugeben. Auch Exceptions können dabei sehr behilflich sein.

_________________
www.SaschaWillems.de | GitHub | Twitter | GPU Datenbanken (Vulkan, GL, GLES)

Nach oben

Billi Berserker

Betreff des Beitrags:

Verfasst: Mo Jul 05, 2004 15:40

DGL Member

Registriert: Di Jun 24, 2003 19:09
Beiträge: 732

Hab mir die Demo noch nicht angeschaut,
aber bezüglich TBitmap32 und PNG bilder.
Jemand ausm SharpE Team hatte mir für SharpDesk ne funktion geschrieben die PNG Dateien mit Alpha Channel in TBitmap32 konvertiert. Wenn du willst kann ich die hier posten =)
(ich kann mir zumindest sonst nicht denken woran es liegt das du noch keinen png support drin hast)

Generell als Tipp für die Arbeit mit Graphics32 :
wenn du Probleme hast dann schau einfach in die Mailingliste von graphics32.
Da kannst du verdammt nützliche sachen finden

Nach oben

Finalspace

Betreff des Beitrags:

Verfasst: Mo Jul 05, 2004 21:54

DGL Member

Registriert: Mi Okt 16, 2002 15:06
Beiträge: 1012

Danke für den Tip billi-san, werd mich in der mailing list mal anmelden.

PNG support Alpha Channel, stimmt daran hab ich gar nich gedacht *g*

Wäre aber interessiert für ne Funktion für PNG Loading mit Bmp32.

@SoS: Ok, betreffend speicher guck ich mal, muss es halt an mehreren rechner testen damit ich das nachvollziehen kann.

Nach oben

Billi Berserker

Betreff des Beitrags:

Verfasst: Mo Jul 05, 2004 22:45

DGL Member

Registriert: Di Jun 24, 2003 19:09
Beiträge: 732

Hab gerade mal bei den GFX Funktionen von SharpDesk etwas rum geschaut,
ich denke mal ne Blend funtion wäre auch nicht unpraktisch?
Naja, hier ein paar nützliche funktionen für deine Skin Engine...

Code:

 
procedure BlendImage(bmp : Tbitmap32; color : Tcolor; alpha:integer);
var
   P           : PColor32;
   I           : integer;
   sum1,sum2   : real;
   CB,CR,CG    : Integer;
   oCB,oCR,oCG : Integer;
   nCB,nCR,nCG : Integer;
   tempAlpha   : integer;
   change      : Integer;
begin
  alpha := min(alpha,255);
  alpha := max(alpha,0);
  CR := GetRValue(colortorgb(color));
  CG := GetGValue(colortorgb(color));
  CB := GetBValue(colortorgb(color));
  sum1 := (CB+CR+CG)/3;
  with bmp do begin
    try
      P := PixelPtr[0, 0];
      for I := 0 to Width * Height - 1 do
      begin
        tempAlpha := (P^ shr 24);
        if tempAlpha <> 0 then begin
          oCR    := (P^ and $00FF0000)shr 16;
          oCG    := (P^ and $0000FF00)shr 8;
          oCB    :=  P^ and $0000FF;
          sum2   := (oCB+oCR+oCG)/3;
          change := round(sum2-sum1);
          nCR    := CR + change;
          nCG    := CG + change;
          nCB    := CB + change;
          nCR    := round((alpha/255)*nCR+((255-alpha)/255)*oCR);
          nCG    := round((alpha/255)*nCG+((255-alpha)/255)*oCG);
          nCB    := round((alpha/255)*nCB+((255-alpha)/255)*oCB);
          if nCB > 255 then nCB := 255
          else if nCB < 0 then nCB := 0;
          if nCR > 255 then nCR := 255
          else if nCR < 0 then nCR := 0;
          if nCG > 255 then nCG := 255
          else if nCG < 0 then nCG := 0;
          P^ := color32(nCR,nCG,nCB,tempAlpha);
        end;
        Inc(P); // proceed to the next pixel
      end;
    finally
    end;
  end;
end;

Hier die Funktion zum PNG laden :

Code:

function LoadPng(Bmp : TBitmap32; IconFile:string) : boolean;
var
   ADIB : TBitmap32;
   i, j: integer;
   P: PColor32;
   A: PByte;
   ABmp: TBitmap;
   APng: TPngObject;
   Canvas: TCanvas;
begin
     result := False;
     APng := TPngObject.Create;
     ABmp := TBitmap.Create;
     ADib := TBitmap32.Create;
     try
        // Load and assign to the a bitmap
        APng.LoadFromfile(IconFile);
        APng.AssignTo(ABmp);
 
        // We now *draw* the bitmap to our bitmap.. this will clear alpha in places
        // where drawn.. so we can use it later
        ADib.SetSize(APng.Width, APng.Height);
        ADib.Clear(clBlack32);
        Canvas := TCanvas.Create;
        try
           Canvas.Handle := ADib.Handle;
           Canvas.Draw(0,0,ABmp);
        finally
               Canvas.Free;
        end;
 
     // Flip the alpha channel
     P := @ADib.Bits[0];
     for i := 0 to ADib.Width * ADib.Height - 1 do
     begin
          P^ := P^ XOR $FF000000;
          inc(P);
     end;
 
     // The previous doesn't handle bitwise alpha info, so we do that here
     for i := 0 to APng.Height - 1 do
     begin
          A := PByte(APng.AlphaScanLine[i]);
          if assigned(A) then
          begin
               P := @ADib.Bits[i * ADib.Width];
               for j := 0 to APng.Width - 1 do
               begin
                    P^ := SetAlpha(P^, A^);
                    inc(P); inc(A);
               end;
          end else break;
     end;
 
     finally
            result := True;
 
            APng.Free;
            ABmp.Free;
            Bmp := ADib;
            Bmp.DrawMode := dmBlend;
     end;
end;

Vielleicht auch noch recht praktisch die funktion um XP icons mit Schatten in ein TBitmap32 umzuwandeln...

Code:

procedure IconToImage(Bmp : TBitmap32; const icon : hicon);
var
   w,h,i    : Integer;
   p        : PColorArray;
   p2       : pColor32;
   bmi      : BITMAPINFO;
   AlphaBmp : Tbitmap32;
   tempbmp  : Tbitmap;
   info     : Ticoninfo;
   dc       : hdc;
   alphaUsed : boolean;
begin
     Alphabmp := nil;
     tempbmp := Tbitmap.Create;
     dc := createcompatibledc(0);
     try
        //get info about icon
        GetIconInfo(icon,info);
        tempbmp.handle := info.hbmColor;
        ///////////////////////////////////////////////////////
        // Here comes a ugly step were it tries to paint it as
        // a 32 bit icon and check if it is successful.
        // If failed it will paint it as an icon with fewer colors.
        // No way of deciding bitcount in the beginning has been
        // found reliable , try if you want too.   /Malx
        ///////////////////////////////////////////////////////
        AlphaUsed := false;
        if true then
        begin //32-bit icon with alpha
              w := tempbmp.Width;
              h := tempbmp.Height;
              Bmp.setsize(w,h);
              with bmi.bmiHeader do
              begin
                   biSize := SizeOf(bmi.bmiHeader);
                   biWidth := w;
                   biHeight := -h;
                   biPlanes := 1;
                   biBitCount := 32;
                   biCompression := BI_RGB;
                   biSizeImage := 0;
                   biXPelsPerMeter := 1; //dont care
                   biYPelsPerMeter := 1; //dont care
                   biClrUsed := 0;
                   biClrImportant := 0;
              end;
              GetMem(p,w*h*SizeOf(TColorRec));
              GetDIBits(tempbmp.Canvas.Handle,tempbmp.Handle,0,h,p,bmi,DIB_RGB_COLORS);
              P2 := Bmp.PixelPtr[0, 0];
              for i := 0 to w*h-1 do
              begin
                   if (p[i].a > 0) then alphaused := true;
                   P2^ := color32(p[i].r,p[i].g,p[i].b,p[i].a);
                   Inc(P2);// proceed to the next pixel
              end;
              FreeMem(p);
        end;
        if not(alphaused) then
        begin // 24,16,8,4,2 bit icons
              Bmp.Assign(tempbmp);
              AlphaBmp := Tbitmap32.Create;
              tempbmp.handle := info.hbmMask;
              AlphaBmp.Assign(tempbmp);
              Invert(AlphaBmp,AlphaBmp);
              Intensitytoalpha(Bmp,AlphaBmp);
        end;
     finally
            DeleteDC(dc);
            AlphaBmp.free;
            tempbmp.free;
     end;
end;

so, jetzt ist aber Schluß...
ich hoffe das hilft dir irgendwie,
hat ne ganze Weile gebraucht eh ich das richtig zum laufen bekommen haben(ohne Hilfe hätte ich es gar nicht geschafft

)
Aber gut zu wissen das noch jemand Graphics32 benutzt =)

Nach oben

Finalspace

Betreff des Beitrags:

Verfasst: Di Jul 06, 2004 14:03

DGL Member

Registriert: Mi Okt 16, 2002 15:06
Beiträge: 1012

Thx, die Blend Funktion ist echt praktisch

Das PNG läuft bei mir nicht... TPngObject kennt mein delphi nicht.
Hmm, ich sollte mir langsam auch mal gedanken machen wegen optimierung.
Zur zeit mach ichs so das ich alle Skin Bitmaps in TBitmaps packe.
Diese dann beim Rendern von einem Control per Layer.Bitmap.Clear; und Layer.Bitmap.Assign(SkinBitmap);
nur so als beispiel, bei Progressbars z.b. da muss ich das ganze so machen, das ich per CopyRect den Balken rauskopiere.
Bei Trackbars sinds 2 Layer, einmal background und bar.

Ich selbst rendere Controls nur welche auch wirklich geändert werden müssen.
Bei Mauserreignisse render ich alle.

so sieht z.b. ne routine aus um TXButton zu zeichnen:

Code:

 
  FLayer.Bitmap.DrawMode := dmBlend;
  FLayer.Location := FloatRect(FX,FY,FX + FW,FY + FH);
  FLayer.Bitmap.SetSize(FW,FH);
 
  if FEnabled then
  begin
    if (not FDown) then
    begin
      if FHover then
        FLayer.Bitmap.Assign(FBitmaps[3])
      else
        FLayer.Bitmap.Assign(FBitmaps[2]);
    end
    else
    begin
      if (FHover) then
        FLayer.Bitmap.Assign(FBitmaps[4])
      else
        FLayer.Bitmap.Assign(FBitmaps[2]);
    end;
  end
  else
    FLayer.Bitmap.Assign(FBitmaps[1]);
 
  AddBitmap32Alpha(FLayer.Bitmap, FBitmaps[0]);
 

Code:

 
procedure TfrmMain.img32LayersMouseDown(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Integer;
  Layer: TCustomLayer);
begin
  // Maus erreignisse abfangen
  MouseEventLayers(X, Y, Shift, True);
  // Layers rendern
  RenderLayers;
 
  // Form bewegen wenn kein control aktiv ist
  if (NoControlHitTest(X, Y)) then
    XMoveControlFromMouseDown(Self, X, Y, 5);
end;
 
procedure TfrmMain.img32LayersMouseMove(Sender: TObject;
  Shift: TShiftState; X, Y: Integer; Layer: TCustomLayer);
begin
  // Maus erreignisse abfangen
  MouseEventLayers(X, Y, Shift, False);
  // Hover erreignisse anfangen
  HoverLayers(X, Y);
  // Layers Rendern
  RenderLayers;
end;
 
procedure TfrmMain.img32LayersMouseUp(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Integer;
  Layer: TCustomLayer);
begin
  // Maus erreignisse abfangen
  MouseEventLayers(X, Y, Shift, False);
  // Layers rendern
  RenderLayers;
end;
 

Hättest da ne idee wie man sowas eleganter lösen kann, bzw resourcenschonender ?
Grade das Renderlayers wird sehr oft aufgerufen, wenn die maus bewegt wird, liegt daran weil ich alle Mauserreignisse selbst abfang.

Nach oben

Billi Berserker

Betreff des Beitrags:

Verfasst: Di Jul 06, 2004 16:37

DGL Member

Registriert: Di Jun 24, 2003 19:09
Beiträge: 732

hm,
also jetzt lädst du alle bilder des Skins in eine Liste mit vielen TBitmaps,
und dann weist du je nach state die einzelnen Bitmaps den Layern zu?
So würde ich es denke ich auch machen,
stelle halt nur ganz sicher das du das BeginUpdate und EndUpdate nicht vergißt.
Und vielleicht noch irgendwelche Abfragen das er wirklich nur neu zeichnett wenn sich etwas ändert. Also nicht beim Maus bewegen sondern nur wenn die Maus den Layer verläßt/betritt so das sich auch das benötigte Bitmap ändert. Bei SharpDesk habe ich das z.B. komplett über MouseEnter und MouseLeave gelöst.
Aber warum lädst du die bilder des skins nicht gleich in eine Liste mit TBitmap32?

TPngObject gibts hier : http://pngdelphi.sourceforge.net/

Nach oben

Finalspace

Betreff des Beitrags:

Verfasst: Mi Jul 07, 2004 09:28

DGL Member

Registriert: Mi Okt 16, 2002 15:06
Beiträge: 1012

Also das mit dem BeginUpdate, EndUpdate funzt irgendwie nicht so wie es soll

Muss das ganze viel mehr optimieren und vor allem will ich auf speicher verbrauch acht geben, weil
ist dir schon aufgefallen das wenn du xenorate startest 5-6 mb an speichern weggeht.
und sobald dus minimierst nur noch 1,6 :p

Ich änder aber vieles, ich hab jetzt Dyn-Pascal mit hilfe von Lars compiled bekommen und es rennt

Werd also das Skinsystem darauf aufbauen.

Nach oben

Billi Berserker

Betreff des Beitrags:

Verfasst: Mi Jul 07, 2004 15:49

DGL Member

Registriert: Di Jun 24, 2003 19:09
Beiträge: 732

du rufst einfach bevor du was an den Layern änderst TImage32.Begin Update auf,
Am Ende machst du TImage32.EndUpdate und alles wird dann neu gezeichnett...
(bin mir jetzt nicht sicher wie es genau war, kann auch TImage32.Bitmap.Beginupdate oder TImage32.Layers.BeginUpdate sein)

Mit der Speicherauslastung,
auf die stolzen 12 MB die Winamp5 braucht wirst du so schnell nicht kommen

Nach oben

Finalspace

Betreff des Beitrags:

Verfasst: Do Jul 08, 2004 07:50

DGL Member

Registriert: Mi Okt 16, 2002 15:06
Beiträge: 1012

12 MB haben die den arsch offen oda was :p
soviel verbraucht ja nichmal die alte Xenorate Version, naja die lag ja teilweise sogar unter 2.9 winamp version

Xenorate rockt halt

Am Lap kann ich nur xeno benutzen, selbst VLC versagt da da es kein gescheiten Helligkeit Support mitbringt.

K, werde das mit dem BeginUpdate und EndUpdate machen.
Muss das ganze system eh neu machen, da ich fehler gemacht habe... naja eignetlich kein fehler, aber umständlich für mich.
Ich hab mir Klassen gemacht für jede Komponente, TXButton, TXLabel, TXScrollLabel, TXProgressbars usw.

Und hab dann einfach die routine für MouseEventLayers immer den source von einem kopiert und halt fürs nächste angepasst.
Das ist verdammt viel aufwand und echt schwachsinnig, ich hätte von anfang an nen TXControl machen soll, welches ein Layer hat, die Standard Eigenschaften wie XPos, YPos, Width, Height, Down, Hover und Enabled.
Naja... ich will das system eh in ne DLL auslagern, zumindest die routinen die WinAPI abhängig sind.
Damit ich später support für WinNT und 9x gewährleisten kann, weil WinAPI routinen laufen nich auf 98, SetLayerWindowAttributes z.b. und wirkt auf jedemfall dann übersichtlicher.

Frage, betreffend Desktop Shells: Ich hab mitterweile echt viele ausprobiert, Deinen, Talisman, Litestep, Blackbox usw.
Aber keiner hat Unicode support, was wirklich wichtig ist für mich da 40% meiner files zu hause sind in japananisch geschrieben mit schriftzeichen

Und Delphi macht standardmässig aus Unicode immer ???? draus, welche der explorer natürlich später nicht finden kann

Aber nun zu meiner frage, ich hab angefangen mit eigenes system (nur für mich) zu machen wo ich so gestalten kann wie ich lust habe und vor allem auf geschwindigkeit achten kann, da ich es ja für mich anpasse und nicht irgendwie ur complex proggen muss. Aber mir ist schon aufgefallen das wenn ich ne app mache, diese auf meine auflösung anpasse, Left 0 und top 0 setzte, dann bleiben sämtliche apps immer im hintergrund, öffne ich den editor ist er davor, klick ich wieder aufen desk, dann isser weg

, Sollte aber ja nich sein... sollte ja nur Deaktiviert sein das fenster von Notepad und nicht hinter den desk rutschen.

Gibts da nen WinAPI befehle, welche man die Z-Order von den Fenstern erzwingen kann ?

*Edit: OK, hat sich erledigt, hab im code von sharpdesk nachgeguckt und habs gefunden: SWP_NOZORDER in WindowPosChanging.

Nach oben

Billi Berserker

Betreff des Beitrags:

Verfasst: Do Jul 08, 2004 16:17

DGL Member

Registriert: Di Jun 24, 2003 19:09
Beiträge: 732

Hui, hätte nicht gedacht das der Code wirklich mal für irgendjemanden nützlich sein könnte

(ich sollte ihn aber mal wieder updaten...)

Ich hatte die alte Xenorate Version vor ner Weile schon mal ausprobiert,
aber irgendwas hat mich daran immer wieder gestört. Hat mich irgendwie nie richtig begeistert,
und seit winamp5 gibts für mich nicht wirklich nen anderen musik player. Aber ich weiß gar nicht mehr was mich an der letzten Xenorate Version so gestört hatte. Ich werds bei gelegenheit nochmal ausprobieren...

Nach oben

Billi Berserker

Betreff des Beitrags:

Verfasst: So Aug 22, 2004 18:03

DGL Member

Registriert: Di Jun 24, 2003 19:09
Beiträge: 732

Als ergänzung zu der IconToImage funktion :
im finally Block muß folgender Code hinzugefügt werden :

Code:

            DeleteObject(info.hbmMask);
            DeleteObject(info.hbmColor);

so das es dann wie folgt aussieht :

Code:

     finally
            DeleteDC(dc);
            AlphaBmp.free;
            tempbmp.free;
            DeleteObject(info.hbmMask);  // WICHTIG
            DeleteObject(info.hbmColor); //  WICHTIG
     end;

Ohne den neuen Code erzeugt die funktion ein weniger lustiges leak von 2 GDI Handlen pro Aufruf...
Problem ist das TIconinfo zwei HBitmaps erzeugt ...
(fragt nicht wie lange ich gesucht habe um das zu finden - ich hasse solche bugs

)

Nach oben

LH_Freak

Betreff des Beitrags:

Verfasst: Mo Jan 31, 2005 17:24

DGL Member

Registriert: So Dez 19, 2004 00:27
Beiträge: 454
Wohnort: Nürnberg

Wie machst du eigentlich des mit dem einfärben von den Bildern?

Nach oben

Seite 1 von 3

[ 36 Beiträge ]

Gehe zu Seite 1, 2, 3 Nächste

Foren-Übersicht » Sonstiges » Meinungen zu den Projekten

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.