DGL • Thema anzeigen - Ellipsoid selber Zeichnen

Ellipsoid selber Zeichnen

Moderator: DGL-Team

Seite 1 von 1

[ 3 Beiträge ]

Vorheriges Thema | Nächstes Thema

Autor

Nachricht

GeorgX

Betreff des Beitrags: Ellipsoid selber Zeichnen

Verfasst: Fr Okt 12, 2007 16:15

DGL Member

Registriert: Mi Okt 10, 2007 14:15
Beiträge: 6

Hi,

ich habe vor kurzem für einen Kurs die Aufgabe bekommen einen Ellipsoid in Opengl selber zu zeichnen.

Das soll ohne die Hilfsfunktionen aus der GLU passieren. Ich möchte also das Mesh aus einem Algorythmus selber erstellen.
Leider habe ich überhaupt keine Idee wie ich anfangen soll. Hat jemand ein Beispiel dafür wie sowas funktioniert oder ein Tutorial oder irgendwelche anderen Hinweise für mich?
Bin für jeden Tip dankbar.

Danke schonmal im vorraus!

Nach oben

MatReno

Betreff des Beitrags:

Verfasst: Fr Okt 12, 2007 16:26

DGL Member

Registriert: Mo Jan 31, 2005 11:02
Beiträge: 432
Wohnort: Rheinlandpfalz

Code:

Procedure DrawSphereObject(radius: Tvector3f; n: Word; typ: Byte; inverted: Boolean;
                           voffset: TVector3f; toffset, tscale: TVector2f);
Var
  alpha   : TVector2f;  // i*beta around x axis
  SinAlpha: TVector2f;  // sin(alpha)
  CosAlpha: TVector2f;  // cos(alpha)
  beta    : Single;     // DegToRad(360° / n)
  delta   : Single;     // j*beta around z axis
  SinDelta: Single;     // sin(delta)
  CosDelta: Single;     // cos(delta)
  h, q    : Word;       // half, quarter
  v, norm : TVector3f;  // vector for normal and vertex
  border  : TVector4i;  // for-loop borders
  i, j    : Integer;
  k       : Byte;
Begin
  VectorAbsolute(radius);
 
  If (n < 4) or (Odd(n)) or (radius[0] = 0) or (radius[1] = 0) or (radius[2] = 0) then
    Exit;
 
  h := n div 2;
  q := n div 4;
 
  If (Odd(h)) then
    inc(q);
 
  Case typ of
    0: border := ToVector4i(  -h,    h-1, -q, q);  // sphere
    1: border := ToVector4i(  -h,    h-1, -q, 0);  // hemisphere x-
    2: border := ToVector4i(  -h,    h-1,  0, q);  // hemisphere x+
    3: border := ToVector4i(-h-q, -h+q-1, -q, q);  // hemisphere y-
    4: border := ToVector4i(  -q,    q-1, -q, q);  // hemisphere y+
    5: border := ToVector4i(  -h,     -1, -q, q);  // hemisphere z-
    6: border := ToVector4i(   0,    h-1, -q, q);  // hemisphere z+
    else Exit;
  End;
 
  beta := 2*PI / n;
 
  For i := border[0] to border[1] do
  Begin
    alpha := ToVector2f(i*beta, (i+1)*beta);
 
    SinAlpha := ToVector2f(sin(alpha[0]), sin(alpha[1]));
    CosAlpha := ToVector2f(cos(alpha[0]), cos(alpha[1]));
 
    glBegin(GL_TRIANGLE_STRIP);
    For j := border[2] to border[3] do
    Begin
      delta := j*beta;
 
      SinDelta := sin(delta);
      CosDelta := cos(delta);
 
      If (inverted) then
        For k := 1 downto 0 do
        Begin
          v := ToVector3f(-SinDelta, -CosAlpha[k]*CosDelta, -SinAlpha[k]*CosDelta);
          norm := VectorNorm(VectorDiv(v, VectorNorm(radius)));
          glNormal3fv(@norm);
          v := VectorAdd(VectorMult(v, VectorInv(radius)), voffset);
          glTexCoord2f((j/n + 0.25)*tscale[0] + toffset[0], ((i+k)/n)*tscale[1] + toffset[1]);
          glvertex3fv(@v);
        End;
 
      If (not inverted) then
        For k := 0 to 1 do
        Begin
          v := ToVector3f(SinDelta, CosAlpha[k]*CosDelta, SinAlpha[k]*CosDelta);
          norm := VectorNorm(VectorDiv(v, VectorNorm(radius)));
          glNormal3fv(@norm);
          v := VectorAdd(VectorMult(v,  radius), voffset);
          glTexCoord2f((j/n + 0.25)*tscale[0] + toffset[0], ((i+k)/n)*tscale[1] + toffset[1]);
          glvertex3fv(@v);
        End
    End;
    glEnd;
 
  End;
End;

Das müsste es schon tun... die Typen (TVector3f etc) und Funktionen kannst du dir hier herholen.
Jetzt brauchst du nur noch die Radien des Ellipsoiden einzusetzen.
Texturkoordinaten und Normalen sollten stimmen

EDIT:
Willkommen im Forum

_________________
http://texelviews.delphigl.com

Nach oben

GeorgX

Betreff des Beitrags:

Verfasst: So Okt 14, 2007 19:55

DGL Member

Registriert: Mi Okt 10, 2007 14:15
Beiträge: 6

Vielen Dank für die schnelle Antwort! Bin leider jetzt erst zum Nachgucken gekommen :-)

Nach oben

Seite 1 von 1

[ 3 Beiträge ]

Foren-Übersicht » Programmierung » OpenGL

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 4 Gäste

Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.